***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 10, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJA3416AE   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 0.79		 kp = 47.0		rb = 3.021e-2)
.model  dds   d(
+   is = 1.901e-9		  n = 1.184		   rs = 4.021e-2
+   eg = 7.918e-1	     trs1 = 3.088e-4 )
.model  dbody d(
+   is = 1.901e-9		  n = 1.184		   rs = 4.021e-2
+   eg = 7.918e-1	     trs1 = 1.588e-4
+  cjo = 8.104e-11	  m = 1.360	 	   vj = 3.593
+   bv = 22			ibv = 250e-6	 
+ tbv1 = 7.015e-4	     tbv2 = 8.045e-7	   tt = 25n)
.model  inter  nmos(
+  vto = 0			 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 4.343e-10	  m = 4.035e-1	   vj = 1.207e-1)
.param
+  cgs = 1.232e-9		cgd = 4.337e-10
+   rd = 1.500e-3		 ra = 1.000e-3	  
+ trd1 = 3.805e-4	     trd2 = 1.085e-4
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}    ic = 0
egv	 2t   3   table   {v(1t, S)} 
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (0.80 , 0.80 ),
+ (1.00 , 1.00 ),
+ (1.20 , 1.22 ),
+ (1.30 , 1.32 ),
+ (1.40 , 1.42 ),
+ (1.50 , 1.50 ),
+ (1.70 , 1.62 ),
+ (1.80 , 1.67 ),
+ (2.00 , 1.79 ),
+ (2.50 , 1.92 ),
+ (3.00 , 2.00 ),
+ (4.00 , 2.10 ),
+ (5.00 , 2.15 ),
+ (6.00 , 2.18 ),
+ (8.00 , 2.20 ),
+ (10.0 , 2.20 ))
egt	  1  2t   value = {4.687e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1},{trd2}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra} 
rs	  3   5   1e-4
ls	  5   S   0.001n 
m1     1t   8   6   6   inter
e1      8   6   4  1t   2
cgd	  7   4   {cgd}   ic = 0
rcgd    7   4   10meg
dgd     6   4   dgd
rdgd    4   6   10meg
m2      7   9  1t  1t   inter
e2      9  1t   4  1t   -2
.ends 
*$
